創建基于Android設備及FMS音視頻應用
通過接下來的學習，我們將了解以下3個關鍵的知識點。
- 客戶端如何創建P2P連接
- 運用Flash Media Server4 來實現P2P連接
- 運用最新的Flash CS5 AIR2.5插件來發布Android的移動設備應用程序
在原有的Flash程序中，客戶端通過RTMP協議與Flash Media Server創建連接，在Flash Media Server端通過SharedObject來管理在線用戶的列表，客戶端之間的通信采用Netconnection的Call的方法來發送視頻邀請相關的信息。
要求
你需要先安裝下列產品:
Flash Professional CS5
Flash Media Server 4
Flash Professional CS5上的AIR 2.5 for Android開發插件
示例文件:
預備知識
- ActionScript 3.0 中級編程水平
- 會運用Flash Pro及Flash Media Server開發項目
客戶端創建與FLASH MEDIA SERVER的RTMFP連接
要創建P2P的應用，首先我們需要與服務器端創建RTMFP（Real Time Media Flow Protocol）協議的連接。我們可以將原有代碼中的RTMP協議直接修改為RTMFP，但是RTMFP協議是基于UDP協議的，并不是所有的網絡環境都支持UDP協議。所以為了我們應用的可用性，我們依然保留RTMP連接方式。 在負責通信的Communicator類中，修改 connect函數為：
- public function connect(rtmp:Boolean=false) : void
- {
- //為函數添加布爾參數，通過參數來切換連接FMS服務器的方式
- //默認情況下我們采用rtmfp的連接
- var url=(rtmp?"rtmp:" : "rtmfp:") + "//"+serverURL+"/vchat"
- nc.connect(url,userName);
- // 判斷當采用rtmfp協議連接時候，增添一個連接時間計數器
- // 通過這個計算器設置的連接超時來判斷rtmfp連接是否成功
- if (!rtmp)
- {
- rtmfpTimer = new Timer(connectTimeout, 1);
- rtmfpTimer.addEventListener(TimerEvent.TIMER_COMPLETE,rtmfpTimeoutHandler)
- rtmfpTimer.start();
- }
- }
添加事件偵聽函數，這個函數在當RTMFP連接失敗的時候，關閉原連接，創建RTMP連接。
- private function rtmfpTimeoutHandler(e:TimerEvent):void
- {
- isRTMFP=false;
- rtmfpTimer.stop();
- rtmfpTimer = null;
- nc.close();
- connect(true);
- }
在原有Netconnection連接狀態偵聽函數 ncStatusHandler中添加代碼：
- if (rtmfpTimer)
- {
- rtmfpTimer.stop();
- rtmfpTimer = null;
- }
這樣當Netconnection連接有響應的時候，關閉計數器。
到此，我們已經將客戶端的連接修改為兼容P2P的RTMFP連接方式。現在我們來看看Flash Media Server端的代碼。
FLASH MEDIA SERVER 4中管理并分配P2P連接
當客戶端與Flash Media Server 4成功創建RTMFP連接的時候，服務器會為每個客戶端連接創建一個256位的唯一ID，通過這個ID，客戶端之間就可以進行P2P連接。
要創建P2P方式的音視頻流，我們就需要通過Flash Media Server 4將客戶端各自對應的此唯一ID發送給通信對方。
在客戶端與FMS連接成功時，FMS將此連接的唯一ID保存在名為farID的屬性值中。打開示例中fms > vchat目錄中的Flash Media Server端腳本main.asc，在其中onConnect函數里，我們將此唯一ID在保存在名為peerID的參數中 。
- application.onConnect = function(client, userName)
- {
- ……
- clientclient.peerID=client.farID;
- ……
- }
在視頻邀請的通信函數videoChat中添加如下代碼：
- case "accept":
- var myPeerID=""
- var otherPeerID=""
- if(userList[myname].protocol=="rtmfp" && userList[othername].protocol=="rtmfp")
- {
- myPeerID=userList[myname].peerID
- otherPeerID=userList[othername].peerID
- }
- userList[othername].call("vc", null, stat, myname,myPeerID);
- userList[myname].call("vc", null, stat,othername,otherPeerID);
上述代碼表示，在一方接收另一方視頻聊天邀請時，我們判斷雙方與FMS的連接 協議是否為RTMFP，如果是，將各自的對等ID傳送給對方。
在修改完畢服務端腳本之后，不要忘記將vchat目錄復制到Flash Media Server的applications子目錄中。
客戶端創建兼容P2P的音視頻交互
現在我們回到客戶端代碼Communicator.as 編輯，在初始化發布音視頻流函數initOutStream中，添加傳遞參數 peerID:String，用來接收FMS服務器發送的對方的peerID。
- initOutStream(user:String,peerID:String)
然后添加代碼：
- if(isRTMFP && peerID!="")
- {
- outStreamDirect = new NetStream(nc, NetStream.DIRECT_CONNECTIONS);
- var c:Object = new Object();
- c.onPeerConnect = function(peer:NetStream):Boolean
- {
- if (outStream)
- {
- outStream.close();
- outStream = null;
- }
- outStreamDirect.attachAudio(Microphone.getMicrophone());
- outStreamDirect.attachCamera(cam);
- return true;
- }
- outStreamDirect.client = c;
- outStreamDirect.publish(mySteamName+"_direct");
- }
上述代碼中，我們首先判斷自己與FMS服務器的連接以及對方是否為RTMFP協議，如果是，我們創建一個通過P2P直連的發布流 outStreamDirect，與原來的發布流區別，我們為這個新的發布流創建了新的名稱"_direct"。
請注意這里我們同時保留了原來的基于FMS的發布流，這是因為，即使音視頻聊天的雙方都跟FMS服務器創建了RTMFP協議，由于不同網絡環境，例如防火墻，路由器的限制等，都有可能讓雙方最終不能創建點對點的連接。所以，我們通過onPeerConnect這個方法來判斷雙方是否P2P連接成功。當 P2P連接成功時，關閉原有的基于RTMP協議的發布流outStream。
通過上述代碼的修改，能保證我們的應用真正的適應各種網絡環境的用戶。
同樣的方法，我們對于播放音視頻流的函數initInStream，也采取同時播放原有流和P2P流的方式。
- if(isRTMFP && peerID!="")
- {
- inStreamDirect=new NetStream(nc,peerID)
- inStreamDirect.addEventListener(NetStatusEvent.NET_STATUS, inStream_NetStatusHandler);
- inStreamDirect.play(user+"_direct");
- }
請注意代碼中新建的播放流inStreamDirect，指定了需要播放的對方的peerID，這個唯一ID就來自與剛才我們修改的FMS服務器端程序。
因為我們同時播放了2個流，所以我們為新建的P2P直連流添加如下的事件偵聽函數 inStream_NetStatusHandler ，這樣在P2P流成功播放的時候，將原有的RTMP協議流關閉，并且將當前顯示的視頻切換到這個流。
- private function inStream_NetStatusHandler(event:NetStatusEvent) : void
- {
- if (event.info.code == "NetStream.Play.Start")
- {
- if(inStream)
- {
- inStream.close();
- inStream = null;
- }
- VideoChat.instance._chatScreen.showUserVideo(inStreamDirect)
- }
- }
最后，為保證我們創建的這個Android應用在實際的移動設備運行過程中，用戶點擊返回鍵或程序關閉時斷開與FMS服務器的連接，在主程序類VideoChat.as中添加代碼
- if(Capabilities.cpuArchitecture=="ARM")
- {
- NativeApplication.nativeApplication.addEventListener(Event.ACTIVATE,
- handleActivate, false, 0, true);
- NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE,
- handleDeactivate, false, 0, true);
- NativeApplication.nativeApplication.addEventListener(KeyboardEvent.KEY_DOWN,
- handleKeys, false, 0, true);
- }
- private function handleActivate(event:Event):void
- {
- NativeApplication.nativeApplication.systemIdleMode = SystemIdleMode.KEEP_AWAKE;
- }
- private function handleDeactivate(event:Event):void
- {
- communicator.onExit()
- NativeApplication.nativeApplication.exit();
- }
- private function handleKeys(event:KeyboardEvent):void
- {
- if(event.keyCode == Keyboard.BACK)
- {
- communicator.onExit()
- NativeApplication.nativeApplication.exit();
- }
- }
同時在 Communicator類中添加onExit函數
- public function onExit():void
- {
- nc.close()
- nc=null;
- }
這樣，當用戶點擊返回鍵或者退出程序的時候，自動關閉與FMS的連接。
到此為止，我們已經將客戶端與FMS4配合支持P2P音視頻流的相關代碼修改完畢。接下來我們將這個程序發布為基于Android移動設備的應用。
運用最新的FLASH PRO AIR2.5插件發布ANDROID移動端應用
由于原始代碼是基于Flash Professional的，所以要方便的發布一個基于Android的移動設備應用，我們可以從Adobe實驗室中下載最新的AIR 2.5 for Flash Pro CS5 插件，下載地址：http://labs.adobe.com/technologies/flashpro_extensionforair/
在安裝好這個插件之后，打開Flash發布設置，選擇AIR Android，點擊打開設置選項。
在通用設置（General）面板中，我們可以設置應用是否全屏，發布名稱等。
在部署(Deployment)面板中，創建你的應用程序證書，在發布之后選項中，如果你的電腦連接了Android的移動設備，可以勾選發布后自動安裝此應用到設備上，并且可以自動運行。
在訪問權限(Permissions)面板中設置此應用的訪問權限，因為我們做的這個應用需要連接網絡及使用攝像頭，所以需要選擇Internet和Camera選項。
發布我們最終修改好的程序，現在你可以通過Android移動設備進行音視頻通訊了。：
下圖為程序在Samsung Galaxy Tab上運行得效果。
關于作者
黃竣 (peter huang)
Adobe Platform Evangelist 國內最早一批Flash開發者之一，Rich Interactive Entertainment（RIE®）創始人。從事近10年的互聯網互動應用及Flash游戲的開發，對Flash游戲、視頻及移動應用開發具有豐富的經驗。目前是Adobe平臺技術傳教士，致力于Flash技術在游戲，視頻方面的應用及推廣。
