[[392807]]

 C語言的循環結構有for循環、while循環、do循環和goto循環。本文介紹前3種循環方式。

1. for循環結構

for循環也可以稱為步進循環，它的特點是常用于已經明確了循環的范圍。看一個簡單的C語言代碼，具體如下： 

#include <stdio.h>  
int main()  
{  
  int nNum = 0, nSum = 0;  
  for ( nNum = 1; nNum <= 100; nNum ++ )  
  {  
    nSum += nNum;  
  }  
  printf("nSum = %d \r\n", nSum); 
  return 0;  
} 

這是很典型的求1～100的累加和的程序。通過這個程序來認識關于for循環結構的反匯編代碼。 

.text:00401028 mov [ebp+nNum], 0  
.text:0040102F mov [ebp+nSum], 0  
.text:00401036 mov [ebp+nNum], 1  
.text:0040103D jmp short LOC_CMP  
.text:0040103F ; ---------------------------------------------------------  
.text:0040103F  
.text:0040103F LOC_STEP: ; CODE XREF: _main+47j  
.text:0040103F mov eax, [ebp+nNum]  
.text:00401042 add eax, 1  
.text:00401045 mov [ebp+nNum], eax  
.text:00401048 
.text:00401048 LOC_CMP: ; CODE XREF: _main+2Dj  
.text:00401048 cmp [ebp+nNum], 64h  
.text:0040104C jg short LOC_ENDFOR  
.text:0040104E mov ecx, [ebp+nSum]  
.text:00401051 add ecx, [ebp+nNum]  
.text:00401054 mov [ebp+nSum], ecx  
.text:00401057 jmp short LOC_STEP  
.text:00401059 ; ---------------------------------------------------------  
.text:00401059  
.text:00401059 LOC_ENDFOR: ; CODE XREF: _main+3Cj  
.text:00401059 mov edx, [ebp+nSum]  
.text:0040105C push edx  
.text:0040105D push offset Format ; "nSum = %d \r\n"  
.text:00401062 call _printf  
.text:00401067 add esp, 8  
.text:0040106A xor eax, eax 

這次的反匯編代碼，修改了其中的變量、標號，看起來更加直觀。從修改的標號來看，for結構可以分為3部分，在LOC_STEP上面的部分是初始化部分，在LOC_STEP下面的部分是修改循環變量的部分，在LOC_CMP下面和LOC_ENDFOR上面部分是比較循環條件和循環體的部分。

for循環的反匯編結構如下： 

; 初始化循環變量  
  jmp LOC_CMP  
LOC_STEP:  
  ; 修改循環變量  
LOC_CMP:  
  ; 循環變量的判斷  
  jxx LOC_ENDFOR  
  ; 循環體  
  jmp LOC_STEP  
LOC_ENDOF: 

再用IDA來看一下生成的流程結構圖，如圖1所示。

圖1  for結構的流程圖

2. do…while循環結構

do循環的循環體總是會被執行一次，這是do循環與while循環的區別。這里還是1～100的累加和代碼，來看一下它的反匯編結構。先看C語言代碼，具體如下： 

#include <stdio.h>  
int main()  
{  
  int nNum = 1, nSum = 0;  
  do  
  {  
    nSum += nNum;  
    nNum ++;  
  } while ( nNum <= 100 );  
  printf("nSum = %d \r\n", nSum);  
  return 0;  
} 

do循環的結構要比for循環的結構簡單很多，反匯編代碼也少很多。先來看一下IDA生成的流程圖，如圖2所示。

圖2  do循環流程圖

反匯編代碼如下： 

.text:00401028 mov [ebp+nNum], 1  
.text:0040102F mov [ebp+nSum], 0  
.text:00401036  
.text:00401036 LOC_DO: ; CODE XREF: _main+3Cj  
.text:00401036 mov eax, [ebp+nSum] 
.text:00401039 add eax, [ebp+nNum]  
.text:0040103C mov [ebp+nSum], eax  
.text:0040103F mov ecx, [ebp+nNum]  
.text:00401042 add ecx, 1  
.text:00401045 mov [ebp+nNum], ecx  
.text:00401048 cmp [ebp+nNum], 64h  
.text:0040104C jle short LOC_DO  
.text:0040104E mov edx, [ebp+nSum]  
.text:00401051 push edx  
.text:00401052 push offset Format ; "nSum = %d \r\n"  
.text:00401057 call _printf  
.text:0040105C add esp, 8  
.text:0040105F xor eax, eax 

do循環的主體就在LOC_DO和0040104C的jle之間。其結構整理如下： 

; 初始化循環變量  
C_DO:  
; 執行循環體  
; 修改循環變量  
; 循環變量的比較  
Jxx LOC_DO  

3. while循環結構

while循環與do循環的區別在于，在進入循環體之前需要先進行一次條件判斷，循環體有可能因為循環條件的不成立而一次也不執行。看1～100累加和的while循環代碼： 

#include <stdio.h>  
int main()  
{  
  int nNum = 1, nSum = 0;  
  while ( nNum <= 100 )  
  {  
    nSum += nNum;  
    nNum ++;  
  }  
  printf("nSum = %d \r\n", nSum);  
  return 0; 
} 

再來看一下它的反匯編代碼，while循環比do循環多了一個條件的判斷，因此會多一條分支。反匯編代碼如下： 

.text:00401028 mov [ebp+nNum], 1  
.text:0040102F mov [ebp+nSum], 0  
.text:00401036  
.text:00401036 LOC_WHILE: ; CODE XREF: _main+3Ej  
.text:00401036 cmp [ebp+nNum], 64h  
.text:0040103A jg short LOC_WHILEEND  
.text:0040103C mov eax, [ebp+nSum]  
.text:0040103F add eax, [ebp+nNum]  
.text:00401042 mov [ebp+nSum], eax  
.text:00401045 mov ecx, [ebp+nNum]  
.text:00401048 add ecx, 1  
.text:0040104B mov [ebp+nNum], ecx  
.text:0040104E jmp short LOC_WHILE  
.text:00401050 ; -----------------------------------------------------------  
.text:00401050  
.text:00401050 LOC_WHILEEND: ; CODE XREF: _main+2Aj  
.text:00401050 mov edx, [ebp+nSum]  
.text:00401053 push edx  
.text:00401054 push offset Format ; "nSum = %d \r\n"  
.text:00401059 call _printf  
.text:0040105E add esp, 8  
.text:00401061 xor eax, eax 

while循環的主要部分全部在LOC_WHILE和LOC_WHILEEND之間。在LOC_WHILE下面的兩句是cmp和jxx指令，在LOC_WHILEEND上面是jmp指令。這兩部分是固定的格式，其結構整理如下： 

  ; 初始化循環變量等  
LOC_WHILE:  
  cmp xxx, xxx  
  jxx LOC_WHILEEND  
  ; 循環體  
  jmp LOC_WHILE  
LOC_WHILEEND: 

再來看一下IDA生成的流程圖，如圖3所示。

圖3  while循環流程圖

對于for循環、do循環和while循環這3種循環而言，do循環的效率顯然高些，而while循環相對來說比for循環效率又高些。