EXECUTE IMMEDIATE代替了以前Oracle中DBMS_SQL package包. 下面就為您介紹Oracle中EXECUTE IMMEDIATE的使用技巧，供您參考。

它解析并馬上執(zhí)行動(dòng)態(tài)的SQL語(yǔ)句或非運(yùn)行時(shí)創(chuàng)建的PL/SQL塊.動(dòng)態(tài)創(chuàng)建和執(zhí)行SQL語(yǔ)句性能超前，EXECUTE IMMEDIATE的目標(biāo)在于減小企業(yè)費(fèi)用并獲得較高的性能，較之以前它相當(dāng)容易編碼.盡管DBMS_SQL仍然可用，但是推薦使用EXECUTE IMMEDIATE,因?yàn)樗@的收益在包之上。

-- 使用技巧

1. EXECUTE IMMEDIATE將不會(huì)提交一個(gè)DML事務(wù)執(zhí)行，應(yīng)該顯式提交
如果通過EXECUTE IMMEDIATE處理DML命令，
那么在完成以前需要顯式提交或者作為EXECUTE IMMEDIATE自己的一部分.
如果通過EXECUTE IMMEDIATE處理DDL命令,它提交所有以前改變的數(shù)據(jù)

2. 不支持返回多行的查詢,這種交互將用臨時(shí)表來存儲(chǔ)記錄(參照例子如下)或者用REF cursors.

3. 當(dāng)執(zhí)行SQL語(yǔ)句時(shí)，不要用分號(hào)，當(dāng)執(zhí)行PL/SQL塊時(shí)，在其尾部用分號(hào).

4. 在Oracle手冊(cè)中，未詳細(xì)覆蓋這些功能。
下面的例子展示了所有用到Execute immediate的可能方面.希望能給你帶來方便.

5. 對(duì)于Forms開發(fā)者,當(dāng)在PL/SQL 8.0.6.3.版本中，F(xiàn)orms 6i不能使用此功能.

EXECUTE IMMEDIATE -- 用法例子

1. 在PL/SQL運(yùn)行DDL語(yǔ)句

begin   
   execute immediate 'set role all';   
end;  

2. 給動(dòng)態(tài)語(yǔ)句傳值(USING 子句)

declare   
   l_depnam varchar2(20) := 'testing';   
   l_loc     varchar2(10) := 'Dubai';   
   begin   
   execute immediate 'insert into dept values   (:1, :2, :3)'   
     using 50, l_depnam, l_loc;   
   commit;   
end;  

3. 從動(dòng)態(tài)語(yǔ)句檢索值(INTO子句)

declare   
   l_cnt     varchar2(20);   
begin   
   execute immediate 'select count(1) from emp'   
     into l_cnt;   
dbms_output.put_line(l_cnt);   
end;  

4. 動(dòng)態(tài)調(diào)用例程.例程中用到的綁定變量參數(shù)必須指定參數(shù)類型.
黓認(rèn)為IN類型,其它類型必須顯式指定

declare   
   l_routin    varchar2(100) := 'gen2161.get_rowcnt';   
   l_tblnam    varchar2(20) := 'emp';   
   l_cnt       number;   
   l_status    varchar2(200);   
begin   
execute immediate 'begin ' || l_routin || '(:2, :3, :4); end;'   
     using in l_tblnam, out l_cnt, in out l_status;   
if l_status != 'OK' then   
      dbms_output.put_line('error');   
end if;   
end;  

5. 將返回值傳遞到PL/SQL記錄類型;同樣也可用%rowtype變量

declare   
type empdtlrec is record (empno   number(4),   
                            ename   varchar2(20),   
                            deptno   number(2));   
empdtl empdtlrec;   
begin   
execute immediate 'select empno, ename, deptno ' ||   
                    'from emp where empno = 7934'   
into empdtl;   
end;  

6. 傳遞并檢索值.INTO子句用在USING子句前

declare   
   l_dept     pls_integer := 20;   
   l_nam      varchar2(20);   
   l_loc      varchar2(20);   
begin   
   execute immediate 'select dname, loc from dept where deptno = :1'   
     into l_nam, l_loc   
     using l_dept ;   
end;  

7. 多行查詢選項(xiàng).對(duì)此選項(xiàng)用insert語(yǔ)句填充臨時(shí)表，
用臨時(shí)表進(jìn)行進(jìn)一步的處理,也可以用REF cursors糾正此缺憾.

declare   
   l_sal    pls_integer := 2000;   
begin   
execute immediate 'insert into temp(empno, ename) ' ||   
            '           select empno, ename from emp ' ||   
            '           where   sal > :1'   
using l_sal;   
commit;   
end;  

對(duì)于處理動(dòng)態(tài)語(yǔ)句,EXECUTE IMMEDIATE 比以前可能用到的更容易并且更高效.
當(dāng)意圖執(zhí)行動(dòng)態(tài)語(yǔ)句時(shí)，適當(dāng)?shù)靥幚懋惓８又匾?應(yīng)該關(guān)注于捕獲所有可能的異常.

【編輯推薦】

詳解oracle授權(quán)語(yǔ)句

Oracle修改用戶語(yǔ)法介紹

Oracle身份驗(yàn)證的三種方法

Oracle默認(rèn)用戶的密碼問題

Oracle游標(biāo)常用屬性