探索 Tcl/Tk 的基礎(chǔ)構(gòu)造，包括用戶輸入、輸出、變量、條件評(píng)估、簡(jiǎn)單函數(shù)和基礎(chǔ)事件驅(qū)動(dòng)編程。

我寫這篇文章的初衷源于我想更深入地利用基于 Tcl 的 Expect。這讓我寫下了以下兩篇文章：通過編寫一個(gè)簡(jiǎn)單的游戲?qū)W習(xí) Tcl 和 通過編寫一個(gè)簡(jiǎn)單的游戲?qū)W習(xí) Expect。

我進(jìn)行了一些 Ansible 自動(dòng)化工作，逐漸積累了一些本地腳本。有些腳本我頻繁使用，以至于以下循環(huán)操作變得有些煩人：

• 打開終端
• 使用 cd 命令跳轉(zhuǎn)至合適的目錄
• 輸入一條帶有若干選項(xiàng)的長(zhǎng)命令啟動(dòng)所需的自動(dòng)化流程

我日常使用的是 macOS。實(shí)際上我更希望有一個(gè)菜單項(xiàng)或者一個(gè)圖標(biāo)，能夠彈出一個(gè)簡(jiǎn)單的界面接受參數(shù)并執(zhí)行我需要的操作，這就像在 Linux 的 KDE 中一樣。

經(jīng)典的 Tcl 類書籍都包含了關(guān)于流行的 Tk 擴(kuò)展的文檔。既然我已經(jīng)深入研究了這個(gè)主題，我嘗試著對(duì)其（即 wish）進(jìn)行編程。

雖然我并非一名 GUI 或者前端開發(fā)者，但我發(fā)現(xiàn) Tcl/Tk 腳本編寫的方式相當(dāng)直接易懂。我很高興能重新審視這個(gè) UNIX 歷史的古老且穩(wěn)定的部分，這種技術(shù)在現(xiàn)代平臺(tái)上依然有用且可用。

安裝 Tcl/Tk

對(duì)于 Linux 系統(tǒng)，你可以按照下面的方式安裝：

$ sudo dnf install tcl
$ which wish
/bin/wish

而在 macOS 上，你可以通過 Homebrew 來安裝最新版的 Tcl/Tk：

$ brew install tcl-tk
$ which wish
/usr/local/bin/wish

編程理念

許多編寫游戲的教程都會(huì)介紹到典型的編程語言結(jié)構(gòu)，如循環(huán)、條件判斷、變量、函數(shù)和過程等等。

在此篇文章中，我想要介紹的是 事件驅(qū)動(dòng)編程。當(dāng)你的程序使用事件驅(qū)動(dòng)編程，它會(huì)進(jìn)入一個(gè)特殊的內(nèi)置循環(huán)，等待特定的事件發(fā)生。當(dāng)這個(gè)特定的事件發(fā)生時(shí)，相應(yīng)的代碼就會(huì)被觸發(fā)，產(chǎn)生預(yù)期的結(jié)果。

這些事件可以包括鍵盤輸入、鼠標(biāo)移動(dòng)、點(diǎn)擊按鈕、定時(shí)器觸發(fā)，甚至是任何你的電腦硬件能夠識(shí)別的事件（可能來自特殊的設(shè)備）。你的程序中的代碼決定了用戶看到了什么，以及程序需要監(jiān)聽什么輸入，當(dāng)這些輸入被接收后程序會(huì)怎么做，然后進(jìn)入事件循環(huán)等待輸入。

這篇文章的理念并沒有脫離我之前的 Tcl 文章太遠(yuǎn)。這里最大的不同在于用 GUI 設(shè)置和用于處理用戶輸入的事件循環(huán)替代了循環(huán)結(jié)構(gòu)。其他的不同則是 GUI 開發(fā)需要采取的各種方式來制作一個(gè)可用的用戶界面。在采用 Tk GUI 開發(fā)的時(shí)候，你需要了解兩個(gè)基礎(chǔ)的概念：部件widget和幾何管理器geometry manager。

部件是構(gòu)成可視化元素的 UI 元素，通過這些元素用戶可以與程序進(jìn)行交互。這其中包括了按鈕、文本區(qū)域、標(biāo)簽和文本輸入框。部件還包括了一些選項(xiàng)選擇，如菜單、復(fù)選框、單選按鈕等。最后，部件也包括了其他的可視化元素，如邊框和線性分隔符。

幾何管理器在放置部件在顯示窗口中的位置上扮演著至關(guān)重要的角色。有一些不同的幾何管理器可以供你使用。在這篇文章中，我主要使用了 grid 幾何來讓部件在整齊的行中進(jìn)行布局。我會(huì)在這篇文章的結(jié)尾地方解釋一些幾何管理器的不同之處。

用 wish 進(jìn)行猜數(shù)字游戲

這個(gè)示例游戲代碼與我其他文章中的示例有所不同，我將它分解為若干部分以方便解釋。

首先創(chuàng)建一個(gè)基本的可執(zhí)行腳本 numgame.wish ：

$ touch numgame.wish
$ chmod 755 numgame.wish

使用你喜歡的文本編輯器打開此文件，輸入下列代碼的第一部分：

#!/usr/bin/env wish
set LOW 1
set HIGH 100
set STATUS ""
set GUESS ""
set num [expr round(rand()*100)]

第一行定義了該腳本將通過 wish 執(zhí)行。接下來，創(chuàng)建了幾個(gè)全局變量。這里我使用全部大寫字母定義全局變量，這些變量將綁定到跟蹤這些值的窗口小部件（LOW、HIGH等等）。

全局變量 num 是游戲玩家要猜測(cè)的隨機(jī)數(shù)值，這個(gè)值是通過 Tcl 的命令執(zhí)行得到并保存到變量中的：

proc Validate {var} {
    if { [string is integer $var] } {
        return 1
    }
    return 0
}

這是一個(gè)驗(yàn)證用戶輸入的特殊函數(shù)，它只接受整數(shù)并拒絕其他所有類型的輸入：

proc check_guess {guess num} {
    global STATUS LOW HIGH GUESS
    if { $guess < $LOW } {
        set STATUS "What?"
    } elseif { $guess > $HIGH } {
        set STATUS "Huh?"
    } elseif { $guess < $num } {
        set STATUS "Too low!"
        set LOW $guess
    } elseif { $guess > $num } {
        set STATUS "Too high!"
        set HIGH $guess
    } else {
        set LOW $guess
        set HIGH $guess
        set STATUS "That's Right!"
        destroy .guess .entry
        bind all <Return> {.quit invoke}
    }
    set GUESS ""
}

這是主要的猜數(shù)邏輯循環(huán)。global 語句讓我們能夠修改在文件開頭創(chuàng)建的全局變量（關(guān)于此主題后面將會(huì)有更多解釋）。這個(gè)條件判斷尋找入力范圍在 1 至 100 之外以及已經(jīng)被用戶猜過的值。有效的猜測(cè)和隨機(jī)值進(jìn)行比較。LOW 和 HIGH 的猜測(cè)會(huì)被追蹤，作為 UI 中的全局變量進(jìn)行報(bào)告。在每一步，全局 STATUS 變量都會(huì)被更新，這個(gè)狀態(tài)信息會(huì)自動(dòng)在 UI 中顯示。

對(duì)于正確的猜測(cè)，destroy 語句會(huì)移除 “Guess” 按鈕以及輸入窗口，并重新綁定回車鍵，以激活 “Quit” 按鈕。

最后的語句 set GUESS "" 用于在下一個(gè)猜測(cè)之前清空輸入窗口。

label .inst -text "Enter a number between: "
label .low -textvariable LOW
label .dash -text "-"
label .high -textvariable HIGH
label .status -text "Status:"
label .result -textvariable STATUS
button .guess -text "Guess" -command { check_guess $GUESS $num }
entry .entry -width 3 -relief sunken -bd 2 -textvariable GUESS -validate all \
    -validatecommand { Validate %P }
focus .entry
button .quit -text "Quit" -command { exit }
bind all <Return> {.guess invoke}

這是設(shè)置用戶界面的部分。前六個(gè)標(biāo)簽語句在你的 UI 上創(chuàng)建了不同的文本展示元素，-textvariable 選項(xiàng)監(jiān)控給定的變量，并自動(dòng)更新標(biāo)簽的值，這展示了全局變量 LOW、HIGH、STATUS 的綁定。

button 行創(chuàng)建了 “Guess” 和 “Quit” 按鈕， -command 選項(xiàng)設(shè)定了當(dāng)按鈕被按下時(shí)要執(zhí)行的操作。按下 “Guess” 按鈕執(zhí)行了上面的 check_guess 函數(shù)以檢查用戶輸入的值。

entry 部件更有趣。它創(chuàng)建了一個(gè)三字符寬的輸入框，并將輸入綁定到 GUESS 全局變量。它還通過 -validatecommand 選項(xiàng)設(shè)置了驗(yàn)證，阻止輸入部件接收除數(shù)字以外的任何內(nèi)容。

focus 命令是用戶界面的一項(xiàng)改進(jìn)，使程序啟動(dòng)時(shí)輸入部件處于激活狀態(tài)。沒有此命令，你需要先點(diǎn)擊輸入部件才可以輸入。

bind 命令允許你在按下回車鍵時(shí)自動(dòng)點(diǎn)擊 “Guess” 按鈕。如果你記得 check_guess 中的內(nèi)容，猜測(cè)正確之后會(huì)重新綁定回車鍵到 “Quit” 按鈕。

最后，這部分設(shè)定了圖形用戶界面的布局：

grid .inst
grid .low .dash .high
grid .status .result
grid .guess .entry
grid .quit

grid 幾何管理器被逐步調(diào)用，以逐漸構(gòu)建出預(yù)期的用戶體驗(yàn)。它主要設(shè)置了五行部件。前三行是顯示不同值的標(biāo)簽，第四行是 “Guess” 按鈕和 entry 部件，最后是 “Quit” 按鈕。

程序到此已經(jīng)初始化完畢，wish shell 進(jìn)入事件循環(huán)，等待用戶輸入整數(shù)并按下按鈕。基于其在被監(jiān)視的全局變量中找到的變化，它會(huì)更新標(biāo)簽。

注意，輸入光標(biāo)開始就在輸入框中，而且按下回車鍵將調(diào)用適當(dāng)且可用的按鈕。

這只是一個(gè)初級(jí)的例子，Tcl/Tk 有許多可以讓間隔、字體、顏色和其他用戶界面方面更具有吸引力的選項(xiàng)，這超出了本文中簡(jiǎn)單 UI 的示例。

運(yùn)行這個(gè)應(yīng)用，你可能會(huì)注意到這些部件看起來并不很精致或現(xiàn)代。這是因?yàn)槲艺谑褂迷嫉慕?jīng)典部件集，它們讓人回憶起 X Windows Motif 的時(shí)代。不過，還有一些默認(rèn)的部件擴(kuò)展，被稱為主題部件，它們可以讓你的應(yīng)用程序有更現(xiàn)代、更精致的外觀和感覺。

啟動(dòng)游戲！

保存文件之后，在終端中運(yùn)行它：

$ ./numgame.wish

在這種情況下，我無法給出控制臺(tái)的輸出，因此這里有一個(gè)動(dòng)畫 GIF 來展示如何玩這個(gè)游戲：

用 Wish 編寫的猜數(shù)游戲

用 Wish 編寫的猜數(shù)游戲

進(jìn)一步了解 Tcl

Tcl 支持命名空間的概念，所以在這里使用的變量并不必須是全局的。你可以把綁定的部件變量組織進(jìn)不同的命名空間。對(duì)于像這樣的簡(jiǎn)單程序，可能并不太需要這么做。但對(duì)于更大規(guī)模的項(xiàng)目，你可能會(huì)考慮這種方法。

proc check_guess 函數(shù)體內(nèi)有一行 global 代碼我之前沒有解釋。在 Tcl 中，所有變量都按值傳遞，函數(shù)體內(nèi)引用的變量的范圍是局部的。在這個(gè)情況下，我希望修改的是全局變量，而不是局部范圍的版本。Tcl 提供了許多方法來引用變量，在執(zhí)行堆棧的更高級(jí)別執(zhí)行代碼。在一些情況下，像這樣的簡(jiǎn)單引用可能帶來一些復(fù)雜性和錯(cuò)誤，但是調(diào)用堆棧的操作非常有力，允許 Tcl 實(shí)現(xiàn)那些在其他語言中實(shí)現(xiàn)起來可能較為復(fù)雜的新的條件和循環(huán)結(jié)構(gòu)。

最后，在這篇文章中，我沒有提到幾何管理器，它們用于以特定的順序展示部件。只有被某種幾何管理器管理的部件才能顯示在屏幕上。grid 管理器相當(dāng)簡(jiǎn)潔，它按照從左到右的方式放置部件。我使用了五個(gè) grid 定義來創(chuàng)建了五行。另外還有兩個(gè)幾何管理器：place 和 pack。pack 管理器將部件圍繞窗口邊緣排列，而 place 管理器允許固定部件的位置。除這些幾何管理器外，還有一些特殊的部件，如 canvas ，text 和 panedwindow，它們可以容納并管理其他部件。你可以在經(jīng)典的 Tcl/Tk 參考指南，以及 Tk 命令 文檔頁(yè)上找到這些部件的全面描述。

繼續(xù)學(xué)習(xí)編程

Tcl 和 Tk 提供了一個(gè)簡(jiǎn)單有效的方法來構(gòu)建圖形用戶界面和事件驅(qū)動(dòng)應(yīng)用程序。這個(gè)簡(jiǎn)單的猜數(shù)游戲只是你能用這些工具做到的事情的起點(diǎn)。通過繼續(xù)學(xué)習(xí)和探索 Tcl 和 Tk，你可以打開構(gòu)建強(qiáng)大且用戶友好的應(yīng)用程序的無數(shù)可能性。繼續(xù)嘗試，繼續(xù)學(xué)習(xí)，看看你新習(xí)得的 Tcl 和 Tk 技能能帶你到哪里。